Problem Statement

A positive integer n is an arithmetic number if the average of its positive divisors is also an integer. Clearly all odd primes p must be arithmetic numbers because their only divisors are 1 and p whose sum is even and hence their average must be an integer. However, the prime number 2 is not an arithmetic number because the average of its divisors is 1.5. 30 is an arithmetic number because its 7 divisors are: [1, 2, 3, 5, 6, 10, 15, 30], their sum is 72 and average 9 which is an integer. Calculate and show here:

1. The first 100 arithmetic numbers.
2. The xth arithmetic number where x = 1,000 and x = 10,000.
3. How many of the first x arithmetic numbers are composite. Note that, technically, the arithmetic number 1 is neither prime nor composite. Carry out the same exercise in 2. and 3. above for x = 100,000 and x = 1,000,000.

Let's start with the solution:

task←{
    facs   ← ⍸0=⍳|⊢
    aritm  ← (0=≢|+/)∘facs
    comp   ← 2<(≢facs)
    aritms ← ⍸aritm¨⍳15000

    ⎕←'First 100 arithmetic numbers:'
    ⎕←10 10⍴aritms
    {
        ⎕←''
        ⎕←'The ',(⍕⍵),'th arithmetic number: ',(⍕aritms[⍵])
        ncomps ← +/comp¨⍵↑aritms
        ⎕←'Of the first ',(⍕⍵),' arithmetic numbers, ',(⍕ncomps),' are composite.'
    }¨10*3 4
}