Source code in the wren programming language

/* Curzon_numbers.wren */

import "./gmp" for Mpz
import "./fmt" for Fmt

for (k in [2, 4, 6, 8, 10]) {
    System.print("The first 50 Curzon numbers using a base of %(k):")
    var count = 0
    var n = 1
    var pow = Mpz.from(k)
    var curzon50 = []
    while (true) {
        var z = pow + Mpz.one
        var d = k*n + 1
        if (z.isDivisibleUi(d)) {
            if (count < 50) curzon50.add(n)
            count = count + 1
            if (count == 50) {
                Fmt.tprint("$4d", curzon50, 10)
                System.write("\nOne thousandth: ")
            }
            if (count == 1000) {
                Fmt.print("$,d", n)
                break
            }
        }
        n = n + 1
        pow.mul(k)
    }
    System.print()
}


import "./math" for Int
import "./fmt" for Fmt

var isCurzon = Fn.new { |n, k|
    var r = k * n
    return Int.modPow(k, n, r+1) == r
}

var k = 2
while (k <= 10) {
    System.print("Curzon numbers with base %(k):")
    var n = 1
    var count = 0
    while (count < 50) {
        if (isCurzon.call(n, k)) {
            Fmt.write("$4d ", n)
            count = count + 1
            if (count % 10 == 0) System.print()
        }
        n = n + 1
    }
    while (true) {
        if (isCurzon.call(n, k)) count = count + 1
        if (count == 1000) break
        n = n + 1
    }
    Fmt.print("1,000th Curzon number with base $d: $,d\n", k, n)
    k = k + 2
}