How to resolve the algorithm Holidays related to Easter step by step in the COBOL programming language
How to resolve the algorithm Holidays related to Easter step by step in the COBOL programming language
Table of Contents
Problem Statement
Calculate the dates of:
As an example, calculate for the first year of each century from; From the year 325 CE on, Easter Sunday has been defined as the first Sunday after the first full moon on or after the day of the March equinox. However, the actual astronomical values for the moments of the full moon and equinox are not used. Instead, approximations are used, the first one being that the equinox is assumed to fall on March 21st every year. The tracking of the moon phases is similarly done with relatively straightforward arithmetic (compared to the sort required for astronomical accuracy) which amounts to maintaining a lunisolar calendar in parallel to our standard purely-solar one. When Pope Gregory reformed the Catholic calendar in 1582 CE, the drifting of Easter with respect to the seasons was the driving motivation, and the rules for determining it (called the computus) were altered to correct that drift. Catholic nations adopted both the new calendar and the new computus right away, while Western Protestant nations adopted them more gradually over the next 350 years or so. Eventually, even nations dominated by the Eastern Orthodox church adopted a similar calendar reform (the Revised Julian calendar), so pretty much the whole world agrees on what day it is for civil purposes. But the Eastern churches never adopted the corresponding Easter rule changes; they still use the original Julian calendar and computus to determine the date of what is known in the West as "Orthodox Easter". Therefore, your output should indicate which computus was used to calculate the dates and, at least for historical dates where the calendar can't be assumed or is location-dependent, which calendar those dates are given in. You may find algorithms on the Computus Wikipedia page. Some of the results: In the year 400 CE, Easter Sunday was April 1st (in the contemporary Julian calendar), making Ascension Thursday May 10th and Pentecost May 20th. It is ahistorical to give a date so far back for either Trinity Sunday or Corpus Christi, neither of which were observed until centuries later, but they would have been May 27th and 31st. If you extend the modern civil calendar back that far, those days are instead assigned the subsequent dates: Easter on April 2nd, Ascension on May 11th, Pentecost on May 21st. Skipping forward to the year 2100 CE, assuming the rules don't change between now and then, the Western churches will observe Easter on March 28, Ascension Thursday May 6th, Pentecost May 16th, Trinity Sunday May 23rd and Corpus Christi May 27th. Heading East, the Orthodox rules place Easter on April 18 in the original Julian calendar; the corresponding civil date is May 2nd. That puts the Ascension on June 10th and Pentecost June 20th. Orthodox Trinity Sunday is the same day as Pentecost, but they observe All Saints' Sunday the following week, June 27th. Corpus Christi is a purely Catholic date that has no Orthodox version.
Let's start with the solution:
Step by Step solution about How to resolve the algorithm Holidays related to Easter step by step in the COBOL programming language
Source code in the cobol programming language
identification division.
program-id. Easter.
environment division.
configuration section.
repository.
function date-of-integer intrinsic
function integer-of-date intrinsic
function mod intrinsic.
data division.
working-storage section.
77 days pic 9(2).
77 a pic 9(2).
77 b pic 9(2).
77 c pic 9(2).
77 d pic 9(2).
77 e pic 9(2).
77 f pic 9(2).
77 g pic 9(2).
77 h pic 9(2).
77 i pic 9(2).
77 k pic 9(2).
77 l pic 9(2).
77 m pic 9(2).
77 week-day pic 9(1).
77 numerator pic 9(4).
77 integer-date pic 9(18).
01 month-tab value "JanFebMarAprMayJunJulAugSepOctNovDec".
05 month-abreviated pic x(3) occurs 12.
01 week-day-tab value "SunMonTueWedThuFriSat".
05 week-day-abreviated pic x(3) occurs 7.
01 easter-date pic 9(8).
01 filler redefines easter-date.
05 easter-year pic 9(4).
05 easter-month pic 9(2).
05 easter-day pic 9(2).
01 holiday-date pic 9(8).
01 filler redefines holiday-date.
05 holiday-year pic 9(4).
05 holiday-month pic 9(2).
05 holiday-day pic 9(2).
01 edt-date.
05 edt-week-day pic x(3).
05 filler pic x value space.
05 edt-day pic z(2).
05 filler pic x value space.
05 edt-month pic x(3).
procedure division.
main.
display "Christian holidays, related to Easter, for each centennial from 1700 to 2100 CE:"
perform varying easter-year from 1700 by 100 until easter-year > 2100
perform output-holydays
end-perform
display " "
display "Christian holidays, related to Easter, for years from 2010 to 2020 CE:"
perform varying easter-year from 2010 by 1 until easter-year > 2020
perform output-holydays
end-perform
display " "
stop run
.
output-holydays.
display easter-year " " no advancing
perform calculate-easter
move 0 to days
perform add-days
display " Easter: " edt-date no advancing
move 39 to days
perform add-days
display " Ascension: " edt-date no advancing
move 49 to days
perform add-days
display " Pentecost: " edt-date no advancing
move 56 to days
perform add-days
display " Trinity: " edt-date no advancing
move 60 to days
perform add-days
display " Corpus: " edt-date
.
calculate-easter.
compute a = mod(easter-year, 19)
compute b = easter-year / 100
compute c = mod(easter-year, 100)
compute d = b / 4
compute e = mod(b, 4)
compute f = (b + 8) / 25
compute g = (b - f + 1) / 3
compute h = mod((19 * a + b - d - g + 15), 30)
compute i = c / 4
compute k = mod(c, 4)
compute l = mod((32 + 2 * e + 2 * i - h - k), 7)
compute m = (a + 11 * h + 22 * l) / 451
compute numerator = h + l - 7 * m + 114
compute easter-month = numerator / 31
compute easter-day = mod(numerator, 31) + 1
.
add-days.
if days = 0
move easter-date to holiday-date
move 1 to week-day
else
compute holiday-date = date-of-integer(integer-of-date(easter-date) + days)
compute week-day = mod(integer-of-date(easter-date) + days, 7) + 1
end-if
move week-day-abreviated(week-day) to edt-week-day
move month-abreviated(holiday-month) to edt-month
move holiday-day to edt-day
.
You may also check:How to resolve the algorithm Caesar cipher step by step in the AutoIt programming language
You may also check:How to resolve the algorithm Draw a pixel step by step in the Ol programming language
You may also check:How to resolve the algorithm Summarize and say sequence step by step in the REXX programming language
You may also check:How to resolve the algorithm File input/output step by step in the UNIX Shell programming language
You may also check:How to resolve the algorithm Program name step by step in the Applesoft BASIC programming language