Problem Statement

Calculate the dates of:

As an example, calculate for the first year of each century from; From the year 325 CE on,   Easter Sunday   has been defined as the first Sunday after the first full moon on or after the day of the March equinox. However, the actual astronomical values for the moments of the full moon and equinox are not used. Instead, approximations are used, the first one being that the equinox is assumed to fall on March 21st every year. The tracking of the moon phases is similarly done with relatively straightforward arithmetic (compared to the sort required for astronomical accuracy) which amounts to maintaining a lunisolar calendar in parallel to our standard purely-solar one. When Pope Gregory reformed the Catholic calendar in 1582 CE, the drifting of Easter with respect to the seasons was the driving motivation, and the rules for determining it (called the computus) were altered to correct that drift. Catholic nations adopted both the new calendar and the new computus right away, while Western Protestant nations adopted them more gradually over the next 350 years or so. Eventually, even nations dominated by the Eastern Orthodox church adopted a similar calendar reform (the Revised Julian calendar), so pretty much the whole world agrees on what day it is for civil purposes. But the Eastern churches never adopted the corresponding Easter rule changes; they still use the original Julian calendar and computus to determine the date of what is known in the West as "Orthodox Easter". Therefore, your output should indicate which computus was used to calculate the dates and, at least for historical dates where the calendar can't be assumed or is location-dependent, which calendar those dates are given in. You may find algorithms on the Computus Wikipedia page. Some of the results: In the year 400 CE, Easter Sunday was April 1st (in the contemporary Julian calendar), making Ascension Thursday May 10th and Pentecost May 20th. It is ahistorical to give a date so far back for either Trinity Sunday or Corpus Christi, neither of which were observed until centuries later, but they would have been May 27th and 31st. If you extend the modern civil calendar back that far, those days are instead assigned the subsequent dates: Easter on April 2nd, Ascension on May 11th, Pentecost on May 21st. Skipping forward to the year 2100 CE, assuming the rules don't change between now and then, the Western churches will observe Easter on March 28, Ascension Thursday May 6th, Pentecost May 16th, Trinity Sunday May 23rd and Corpus Christi May 27th. Heading East, the Orthodox rules place Easter on April 18 in the original Julian calendar; the corresponding civil date is May 2nd. That puts the Ascension on June 10th and Pentecost June 20th. Orthodox Trinity Sunday is the same day as Pentecost, but they observe All Saints' Sunday the following week, June 27th. Corpus Christi is a purely Catholic date that has no Orthodox version.

Let's start with the solution:

DataSection
  C_DAYS:
  Data.i 0,39,49,56,60
  END_C_DAYS:
  DAYS_MT:
  Data.i 0,31,28,31,30,31,30,31,31,30,31,30,31
  END_DAYS_MT:
EndDataSection

Dim m.s{3}(12)  : PokeS(@m(),"___JanFebMarAprMayJunJulAugSepOctNovDec")
Dim dom.i(12)   : CopyMemory(?DAYS_MT,@dom(),?END_DAYS_MT-?DAYS_MT)
Structure tDate : yyyy.i : mm.i : dd.i : EndStructure
Define.tDate DateTime, BufDateTime

Procedure.b IsLeap(y.i)
  ProcedureReturn Bool( y % 4 = 0 ) & Bool( y % 100 <> 0 ) | Bool( y % 400 = 0 )
EndProcedure

Procedure.i DayOfMt(mm.i,yyyy.i)
  Shared dom()
  If mm=2 And IsLeap(yyyy) : ProcedureReturn 29 : Else : ProcedureReturn dom(mm) : EndIf
EndProcedure

Procedure delta(*pDate.tDate,AddDays.i)  
  *pDate\dd+AddDays
  dom.i=DayOfMt(*pDate\mm,*pDate\yyyy)
  While *pDate\dd-dom>0
    *pDate\mm+1
    If *pDate\mm>12 : *pDate\mm=1 : *pDate\yyyy+1 : EndIf
    *pDate\dd-dom
    dom=DayOfMt(*pDate\mm,*pDate\yyyy)
  Wend
EndProcedure

Procedure dt(y.i)
  a.i=y%19
  b.i=y/100
  c.i=y%100
  d.i=b/4
  e.i=b%4
  f.i=(b+8)/25
  g.i=(b-f+1)/3
  h.i=(19*a+b-d-g+15)%30
  i.i=c/4
  k.i=c%4
  l.i=(32+2*e+2*i-h-k)%7
  m.i=(a+11*h+22*l)/451
  num.i=h+l-7*m+114
  mt.i=num/31
  dy.i=(num%31)+1
  Shared DateTime
  DateTime\yyyy=y
  DateTime\mm=mt
  DateTime\dd=dy  
EndProcedure

Macro PutTab(i)  
  dt(i) : BufDateTime=DateTime : r$=RSet(Str(DateTime\yyyy),4)
  *p_C_Days=?C_DAYS
  While *p_C_Days<?END_C_DAYS
    delta(@DateTime,PeekI(*p_C_Days))
    r$+Space(5)+RSet(Str(DateTime\dd),2,"0")+" "+m(DateTime\mm)
    DateTime=BufDateTime
    *p_C_Days+SizeOf(Integer)
  Wend
EndMacro

OpenConsole()
PrintN("Year"+Space(5)+"Easter  Ascension  Pentecost    Trinity  C/Christi")
PrintN(" CE "+Space(5)+"Sunday  Thursday    Sunday      Sunday   Thursday")
PrintN("----"+Space(5)+"------  --------- ----------    -------  ---------")
For i=400 To 2100 Step 100 : PutTab(i) : PrintN(r$) : Next  
PrintN("")
For i=2010 To 2020 : PutTab(i) : PrintN(r$) : Next      
Input()