Problem Statement

Calculate the dates of:

As an example, calculate for the first year of each century from; From the year 325 CE on,   Easter Sunday   has been defined as the first Sunday after the first full moon on or after the day of the March equinox. However, the actual astronomical values for the moments of the full moon and equinox are not used. Instead, approximations are used, the first one being that the equinox is assumed to fall on March 21st every year. The tracking of the moon phases is similarly done with relatively straightforward arithmetic (compared to the sort required for astronomical accuracy) which amounts to maintaining a lunisolar calendar in parallel to our standard purely-solar one. When Pope Gregory reformed the Catholic calendar in 1582 CE, the drifting of Easter with respect to the seasons was the driving motivation, and the rules for determining it (called the computus) were altered to correct that drift. Catholic nations adopted both the new calendar and the new computus right away, while Western Protestant nations adopted them more gradually over the next 350 years or so. Eventually, even nations dominated by the Eastern Orthodox church adopted a similar calendar reform (the Revised Julian calendar), so pretty much the whole world agrees on what day it is for civil purposes. But the Eastern churches never adopted the corresponding Easter rule changes; they still use the original Julian calendar and computus to determine the date of what is known in the West as "Orthodox Easter". Therefore, your output should indicate which computus was used to calculate the dates and, at least for historical dates where the calendar can't be assumed or is location-dependent, which calendar those dates are given in. You may find algorithms on the Computus Wikipedia page. Some of the results: In the year 400 CE, Easter Sunday was April 1st (in the contemporary Julian calendar), making Ascension Thursday May 10th and Pentecost May 20th. It is ahistorical to give a date so far back for either Trinity Sunday or Corpus Christi, neither of which were observed until centuries later, but they would have been May 27th and 31st. If you extend the modern civil calendar back that far, those days are instead assigned the subsequent dates: Easter on April 2nd, Ascension on May 11th, Pentecost on May 21st. Skipping forward to the year 2100 CE, assuming the rules don't change between now and then, the Western churches will observe Easter on March 28, Ascension Thursday May 6th, Pentecost May 16th, Trinity Sunday May 23rd and Corpus Christi May 27th. Heading East, the Orthodox rules place Easter on April 18 in the original Julian calendar; the corresponding civil date is May 2nd. That puts the Ascension on June 10th and Pentecost June 20th. Orthodox Trinity Sunday is the same day as Pentecost, but they observe All Saints' Sunday the following week, June 27th. Corpus Christi is a purely Catholic date that has no Orthodox version.

Let's start with the solution:

  [ dup 19 mod 19 *
    15 + 30 mod
    swap dup 4 mod 2 *
    swap 7 mod 4 * +
    over - 34 + 7 mod +
    114 + 31 /mod 1+ ]       is julian    (   y --> m d )

  [ dup 19 mod 19 *
    over 100 / +
    over 400 / -
    swap 100 / 8 * 13 +
    25 / - 15 + 30 mod ]     is hge       (   y --> n   )

  [ dup 100 / 4 mod 2 * 32 +
    over 100 mod 4 / 2 * +
    over hge -
    swap 4 mod - 7 mod ]     is lge       (   y --> n   )

  [ dup 19 mod
    over hge 11 * +
    swap lge 19 * + 443 / ]  is mge       (   y --> n   )

  [ dup hge
    over lge +
    swap mge 7 * -
    90 + 25 / ]              is nge       (   y --> n   )

  [ dup hge
    over lge +
    over mge 7 * +
    swap nge 33 * +
    19 + 32 mod ]            is pge       (   y --> n   )

  [ dup nge swap pge ]       is gregorian (   y --> m d )

  [ dup 1583 < iff
      julian
    else gregorian ]         is easter    (   y --> m d )

   [ dip 1+ 9 +
    dup 31 > if
      [ dip 1+ 31 - ] ]      is ascension ( m d -->     )

  [ dip 1+ 19 +
    dup 31 > if
      [ dip 1+ 31 - ] ]      is pentecost ( m d -->     )

  [ dip 1+ 26 +
    dup 31 > if
      [ dip 1+ 31 - ] ]      is trinity   ( m d -->     )

  [ dip 1+ 30 +
    dup 31 > if
      [ dip 1+ 31 - ] ]      is corpus    ( m d -->     )

  [ swap 3 -
    [ table
      $ "Mar" $ "Apr"
      $ "May" $ "Jun" ]
    do echo$ sp
    dup 10 < if [ say "0" ]
    echo ]                   is echodate  ( m d -->     )

  [ dup 1000 < if sp
    dup echo say "   "
    easter 2dup echodate
    say "    "
    2dup ascension echodate
    say "    "
    2dup pentecost echodate
    say "    "
    2dup trinity echodate
    say "    "
    corpus echodate cr ]     is echodates (   y -->     )

  say "Year   Easter   Ascension            Trinity  Corpus"
  cr
  say "(CE)   Sunday   Thursday  Pentecost  Sunday   Christi"
  cr cr
  18 times
    [ i^ 100 * 400 + echodates ]
  cr
  11 times
    [ i^ 2010 + echodates ]