Source code in the aikido programming language

var str = "hello world"
foreach ch str {    // you can also use an optional 'in'
    println (ch)   // one character at a time
}

var vec = [1,2,3,4]
foreach v vec {    // you can also use an optional 'in'
    println (v)
}

var cities = {"San Ramon": 50000, "Walnut Creek": 70000, "San Francisco": 700000}   // map literal
foreach city cities {
    println (city.first + " has population " + city.second)
}

foreach i 100 {
    println (i)    // prints values 0..99
}

foreach i 10..20 {
    println (i)     // prints values 10..20
}

var a = 20
var b = 10
foreach i a..b {
    println (i)   // prints values from a to b (20..10)
}

class List {
    class Element (public data) {
        public var next = null
    }
    var start = null

    public function insert (data) {
        var element = new Element (data)
        element.next = start
        start = element
    }

    public operator foreach (var iter) {
        if (typeof(iter) == "none") {   // first iteration
            iter = start
            return iter.data
        } elif (iter.next == null) {    // check for last iteration
            iter = none
        } else {
            iter = iter.next      // somewhere in the middle
            return iter.data
        }
    }

}

var list = new List()
list.insert (1)
list.insert (2)
list.insert (4)

foreach n list {
    println (n)
}

// coroutine to generate the squares of a sequence of numbers
function squares (start, end) {
    for (var i = start ; i < end ; i++) {
        yield i*i
    }
}

var start = 10
var end = 20

foreach s squares (start, end) {
    println (s)
}

var s = openin ("input.txt")
foreach line s {
    print (line)
}

enum Color { 
   RED, GREEN, BLUE
}

foreach color Color {
    println (color)
}