Problem Statement

S-Expressions   are one convenient way to parse and store data.

Write a simple reader and writer for S-Expressions that handles quoted and unquoted strings, integers and floats. The reader should read a single but nested S-Expression from a string and store it in a suitable datastructure (list, array, etc). Newlines and other whitespace may be ignored unless contained within a quoted string. “()”   inside quoted strings are not interpreted, but treated as part of the string. Handling escaped quotes inside a string is optional;   thus “(foo"bar)” maybe treated as a string “foo"bar”, or as an error. For this, the reader need not recognize “\” for escaping, but should, in addition, recognize numbers if the language has appropriate datatypes. Languages that support it may treat unquoted strings as symbols. Note that with the exception of “()"” (“\” if escaping is supported) and whitespace there are no special characters. Anything else is allowed without quotes. The reader should be able to read the following input and turn it into a native datastructure. (see the Pike, Python and Ruby implementations for examples of native data structures.) The writer should be able to take the produced list and turn it into a new S-Expression. Strings that don't contain whitespace or parentheses () don't need to be quoted in the resulting S-Expression, but as a simplification, any string may be quoted.

Let the writer produce pretty printed output with indenting and line-breaks.

Let's start with the solution:

# PEG infrastructure
def star(E): ((E | star(E)) // .) ;

### Helper functions:
# Consume a regular expression rooted at the start of .remainder, or emit empty;
# on success, update .remainder and set .match but do NOT update .result
def consume($re):
  # on failure, match yields empty
  (.remainder | match("^" + $re)) as $match
  | .remainder |= .[$match.length :]
  | .match = $match.string;

def parse($re):
  consume($re)
  | .result = .result + [.match] ;

def parseNumber($re):
  consume($re)
  | .result = .result + [.match|tonumber] ;

def eos: select(.remainder == "");

# whitespace
def ws: consume("[ \t\r\n]*");

def box(E):
  ((.result = null) | E) as $e
  | .remainder = $e.remainder
  | .result += [$e.result]  # the magic sauce
  ;

# S-expressions

# Input: a string
# Output: an array representation of the input if it is an S-expression
def SExpression:
  def string:     consume("\"") | parse("[^\"]") | consume("\"");
  def identifier: parse("[^ \t\n\r()]+");
  def decimal:    parseNumber("[0-9]+([.][0-9]*)?");
  def hex:        parse("0x[0-9A-Fa-f]+") ;
  def number:     hex // decimal;
  def atom:       ws | (string // number // identifier);

  def SExpr:      ws | consume("[(]") | ws | box(star(atom // SExpr)) | consume("[)]");

  {remainder: .} | SExpr | ws | eos | .result;

SExpression