Problem Statement

Assume functions   a   and   b   return boolean values,   and further, the execution of function   b   takes considerable resources without side effects, and is to be minimized. If we needed to compute the conjunction   (and): Then it would be best to not compute the value of   b()   if the value of   a()   is computed as   false,   as the value of   x   can then only ever be   false. Similarly, if we needed to compute the disjunction (or): Then it would be best to not compute the value of   b()   if the value of   a()   is computed as   true,   as the value of   y   can then only ever be   true. Some languages will stop further computation of boolean equations as soon as the result is known, so-called   short-circuit evaluation   of boolean expressions

Create two functions named   a   and   b,   that take and return the same boolean value. The functions should also print their name whenever they are called. Calculate and assign the values of the following equations to a variable in such a way that function   b   is only called when necessary: If the language does not have short-circuit evaluation, this might be achieved with nested     if     statements.

Let's start with the solution:

MODULE ShortCircuit;
FROM FormatString IMPORT FormatString;
FROM Terminal IMPORT WriteString,WriteLn,ReadChar;

PROCEDURE a(v : BOOLEAN) : BOOLEAN;
VAR buf : ARRAY[0..63] OF CHAR;
BEGIN
    FormatString("    # Called function a(%b)\n", buf, v);
    WriteString(buf);
    RETURN v
END a;

PROCEDURE b(v : BOOLEAN) : BOOLEAN;
VAR buf : ARRAY[0..63] OF CHAR;
BEGIN
    FormatString("    # Called function b(%b)\n", buf, v);
    WriteString(buf);
    RETURN v
END b;

PROCEDURE Print(x,y : BOOLEAN);
VAR buf : ARRAY[0..63] OF CHAR;
VAR temp : BOOLEAN;
BEGIN
    FormatString("a(%b) AND b(%b)\n", buf, x, y);
    WriteString(buf);
    temp := a(x) AND b(y);

    FormatString("a(%b) OR b(%b)\n", buf, x, y);
    WriteString(buf);
    temp := a(x) OR b(y);

    WriteLn;
END Print;

BEGIN
    Print(FALSE,FALSE);
    Print(FALSE,TRUE);
    Print(TRUE,TRUE);
    Print(TRUE,FALSE);
    ReadChar
END ShortCircuit.