Problem Statement

Assume functions   a   and   b   return boolean values,   and further, the execution of function   b   takes considerable resources without side effects, and is to be minimized. If we needed to compute the conjunction   (and): Then it would be best to not compute the value of   b()   if the value of   a()   is computed as   false,   as the value of   x   can then only ever be   false. Similarly, if we needed to compute the disjunction (or): Then it would be best to not compute the value of   b()   if the value of   a()   is computed as   true,   as the value of   y   can then only ever be   true. Some languages will stop further computation of boolean equations as soon as the result is known, so-called   short-circuit evaluation   of boolean expressions

Create two functions named   a   and   b,   that take and return the same boolean value. The functions should also print their name whenever they are called. Calculate and assign the values of the following equations to a variable in such a way that function   b   is only called when necessary: If the language does not have short-circuit evaluation, this might be achieved with nested     if     statements.

Let's start with the solution:

Module Module1

    Function A(v As Boolean) As Boolean
        Console.WriteLine("a")
        Return v
    End Function

    Function B(v As Boolean) As Boolean
        Console.WriteLine("b")
        Return v
    End Function

    Sub Test(i As Boolean, j As Boolean)
        Console.WriteLine("{0} and {1} = {2} (eager evaluation)", i, j, A(i) And B(j))
        Console.WriteLine("{0} or {1} = {2} (eager evaluation)", i, j, A(i) Or B(j))
        Console.WriteLine("{0} and {1} = {2} (lazy evaluation)", i, j, A(i) AndAlso B(j))
        Console.WriteLine("{0} or {1} = {2} (lazy evaluation)", i, j, A(i) OrElse B(j))

        Console.WriteLine()
    End Sub

    Sub Main()
        Test(False, False)
        Test(False, True)
        Test(True, False)
        Test(True, True)
    End Sub

End Module