How to resolve the algorithm Stem-and-leaf plot step by step in the REXX programming language
Published on 12 May 2024 09:40 PM
How to resolve the algorithm Stem-and-leaf plot step by step in the REXX programming language
Table of Contents
Problem Statement
Create a well-formatted stem-and-leaf plot from the following data set, where the leaves are the last digits: The primary intent of this task is the presentation of information. It is acceptable to hardcode the data set or characteristics of it (such as what the stems are) in the example, insofar as it is impractical to make the example generic to any data set. For example, in a computation-less language like HTML the data set may be entirely prearranged within the example; the interesting characteristics are how the proper visual formatting is arranged. If possible, the output should not be a bitmap image. Monospaced plain text is acceptable, but do better if you can. It may be a window, i.e. not a file.
Note: If you wish to try multiple data sets, you might try this generator.
Let's start with the solution:
Step by Step solution about How to resolve the algorithm Stem-and-leaf plot step by step in the REXX programming language
Source code in the rexx programming language
/*REXX program displays a stem and leaf plot of any non-negative numbers [can include 0]*/
parse arg @ /* [↓] Not specified? Then use default*/
if @='' then @=12 127 28 42 39 113 42 18 44 118 44 37 113 124 37 48 127 36 29 31 125 139,
131 115 105 132 104 123 35 113 122 42 117 119 58 109 23 105 63 27 44 105 99 41 128 121,
116 125 32 61 37 127 29 113 121 58 114 126 53 114 96 25 109 7 31 141 46 13 27 43 117,
116 27 7 68 40 31 115 124 42 128 52 71 118 117 38 27 106 33 117 116 111 40 119 47 105,
57 122 109 124 115 43 120 43 27 27 18 28 48 125 107 114 34 133 45 120 30 127 31 116 146
#.=; bot=.; top=. /* [↑] define all #. elements as null.*/
do j=1 for words(@); y=word(@, j) /*◄─── process each number in the list.*/
if \datatype(y,"N") then do; say '***error*** item' j "isn't numeric:" y; exit; end
if y<0 then do; say '***error*** item' j "is negative:" y; exit; end
n=format(y, , 0) / 1 /*normalize the numbers (not malformed)*/
stem=word(left(n, length(n) -1) 0, 1) /*obtain stem (1st digits) from number.*/
parse var n '' -1 leaf; _=stem * sign(n) /* " leaf (last digit) " " */
if bot==. then do; bot=_; top=_; end /*handle the first case for TOP and BOT*/
bot=min(bot, _); top=max(top, _) /*obtain the minimum and maximum so far*/
#.stem.leaf= #.stem.leaf leaf /*construct sorted stem-and-leaf entry.*/
end /*j*/
w=max(length(min), length(max) ) + 1 /*W: used to right justify the output.*/
/* [↓] display the stem-and-leaf plot.*/
do k=bot to top; $= /*$: is the output string, a plot line*/
do m=0 for 10; $=$ #.k.m /*build a line for the stem─&─leaf plot*/
end /*m*/
say right(k, w) '║' space($) /*display a line of stem─and─leaf plot.*/
end /*k*/ /*stick a fork in it, we're all done. */
/*REXX program displays a stem─and─leaf plot of any real numbers [can be: neg, 0, pos].*/
parse arg @ /*obtain optional arguments from the CL*/
if @='' then @='15 14 3 2 1 0 -1 -2 -3 -14 -15' /*Not specified? Then use the default.*/
#.=; bot=.; top=.; z=. /* [↑] define all #. elements as null.*/
do j=1 for words(@); y=word(@, j) /*◄─── process each number in the list.*/
if \datatype(y,"N") then do; say '***error*** item' j "isn't numeric:" y; exit; end
n=format(y,,0)/1; an=abs(n); s=sign(n) /*normalize the numbers (not malformed)*/
stem=left(an, length(an) -1)
if stem=='' then if s>=0 then stem=0 /*handle case of one-digit positive #. */
else stem='-0' /* " " " " " negative " */
else stem=s * stem /* " " " a multi-digit number.*/
parse var n '' -1 leaf /*obtain the leaf (the last digit) of #*/
if bot==. then do; bot=stem; top=bot; end /*handle the first case for TOP and BOT*/
bot=min(bot, stem); top=max(top, stem) /*obtain the minimum and maximum so far*/
if stem=='-0' then z=0 /*use Z as a flag to show negative 0.*/
#.stem.leaf= #.stem.leaf leaf /*construct sorted stem-and-leaf entry.*/
end /*j*/
w=max(length(min), length(max) ) + 1 /*W: used to right─justify the output.*/
!='-0' /* [↓] display the stem-and-leaf plot.*/
do k=bot to top; $= /*$: is the output string, a plot line*/
if k==z then do /*handle a special case for negative 0.*/
do s=0 for 10; $=$ #.!.s /*build a line for the stem─&─leaf plot*/
end /*s*/ /* [↑] address special case of -zero.*/
say right(!, w) '║' space($) /*display a line of stem─and─leaf plot.*/
end /* [↑] handles special case of -zero.*/
$= /*a new plot line (of output). */
do m=0 for 10; $=$ #.k.m /*build a line for the stem─&─leaf plot*/
end /*m*/
say right(k, w) '║' space($) /*display a line of stem─and─leaf plot.*/
end /*k*/ /*stick a fork in it, we're all done. */
You may also check:How to resolve the algorithm Tree traversal step by step in the PicoLisp programming language
You may also check:How to resolve the algorithm Return multiple values step by step in the Erlang programming language
You may also check:How to resolve the algorithm XML/Input step by step in the Wren programming language
You may also check:How to resolve the algorithm Arena storage pool step by step in the PARI/GP programming language
You may also check:How to resolve the algorithm String concatenation step by step in the GlovePIE programming language