How to resolve the algorithm Successive prime differences step by step in the AWK programming language

Published on 12 May 2024 09:40 PM
#Awk

How to resolve the algorithm Successive prime differences step by step in the AWK programming language

Table of Contents

Problem Statement

The series of increasing prime numbers begins: 2, 3, 5, 7, 11, 13, 17, 19, 23, 29, ... The task applies a filter to the series returning groups of successive primes, (s'primes), that differ from the next by a given value or values. Example 1: Specifying that the difference between s'primes be 2 leads to the groups: (Known as Twin primes or Prime pairs) Example 2: Specifying more than one difference between s'primes leads to groups of size one greater than the number of differences. Differences of 2, 4 leads to the groups: In the first group 7 is two more than 5 and 11 is four more than 7; as well as 5, 7, and 11 being successive primes. Differences are checked in the order of the values given, (differences of 4, 2 would give different groups entirely). Note: Generation of a list of primes is a secondary aspect of the task. Use of a built in function, well known library, or importing/use of prime generators from other Rosetta Code tasks is encouraged.

Let's start with the solution:

Step by Step solution about How to resolve the algorithm Successive prime differences step by step in the AWK programming language

Source code in the awk programming language

# syntax: GAWK -f SUCCESSIVE_PRIME_DIFFERENCES.AWK
BEGIN {
    for (i=lo=0; i<=hi=1000000; i++) {
      if (is_prime(i)) {
        p_arr[++p] = i
      }
    }
    printf("there are %d primes between %d - %d\n",p,lo,hi)
    fmt = "%-11s %5s %-15s %s\n"
    printf(fmt,"differences","count","first group","last group")
    for (a=1; a<=split("2;1;2,2;2,4;4,2;6,4,2;2,4,6;100;112",diff_arr,";"); a++) {
      diff_leng = split(diff_arr[a],tmp_arr,",")
      first_set = last_set = ""
      count = 0
      for (b=1; b<=p; b++) {
        str = ""
        for (c=1; c<=diff_leng; c++) {
          if (p_arr[b+c-1] + tmp_arr[c] == p_arr[b+c]) {
            str = (str == "") ? (p_arr[b+c-1] "," p_arr[b+c]) : (str "," p_arr[b+c])
          }
        }
        if (gsub(/,/,"&",str) == diff_leng) {
          count++
          if (first_set == "") {
            first_set = str
          }
          last_set = str
        }
      }
      printf(fmt,diff_arr[a],count,first_set,last_set)
    }
    exit(0)
}
function is_prime(x,  i) {
    if (x <= 1) {
      return(0)
    }
    for (i=2; i<=int(sqrt(x)); i++) {
      if (x % i == 0) {
        return(0)
      }
    }
    return(1)
}

You may also check:How to resolve the algorithm Narcissist step by step in the Haskell programming language
You may also check:How to resolve the algorithm Sort an integer array step by step in the Kotlin programming language
You may also check:How to resolve the algorithm Hash from two arrays step by step in the Picat programming language
You may also check:How to resolve the algorithm Animate a pendulum step by step in the smart BASIC programming language
You may also check:How to resolve the algorithm Honeycombs step by step in the MATLAB programming language