Problem Statement

When counting integers in binary, if you put a (binary) point to the right of the count then the column immediately to the left denotes a digit with a multiplier of

2

0

{\displaystyle 2^{0}}

; the digit in the next column to the left has a multiplier of

2

1

{\displaystyle 2^{1}}

; and so on. So in the following table: the binary number "10" is

1 ×

2

1

0 ×

2

0

{\displaystyle 1\times 2^{1}+0\times 2^{0}}

. You can also have binary digits to the right of the “point”, just as in the decimal number system. In that case, the digit in the place immediately to the right of the point has a weight of

2

− 1

{\displaystyle 2^{-1}}

, or

1

/

2

{\displaystyle 1/2}

. The weight for the second column to the right of the point is

2

− 2

{\displaystyle 2^{-2}}

or

1

/

4

{\displaystyle 1/4}

. And so on. If you take the integer binary count of the first table, and reflect the digits about the binary point, you end up with the van der Corput sequence of numbers in base 2. The third member of the sequence, binary 0.01, is therefore

0 ×

2

− 1

1 ×

2

− 2

{\displaystyle 0\times 2^{-1}+1\times 2^{-2}}

or

1

/

4

{\displaystyle 1/4}

. This sequence is also a superset of the numbers representable by the "fraction" field of an old IEEE floating point standard. In that standard, the "fraction" field represented the fractional part of a binary number beginning with "1." e.g. 1.101001101. Hint A hint at a way to generate members of the sequence is to modify a routine used to change the base of an integer: the above showing that 11 in decimal is

1 ×

2

3

0 ×

2

2

1 ×

2

1

1 ×

2

0

{\displaystyle 1\times 2^{3}+0\times 2^{2}+1\times 2^{1}+1\times 2^{0}}

. Reflected this would become .1101 or

1 ×

2

− 1

1 ×

2

− 2

0 ×

2

− 3

1 ×

2

− 4

{\displaystyle 1\times 2^{-1}+1\times 2^{-2}+0\times 2^{-3}+1\times 2^{-4}}

Let's start with the solution:

(defn van-der-corput
  "Get the nth element of the van der Corput sequence."
  ([n]
   ;; Default base = 2
   (van-der-corput n 2))
  ([n base]
   (let [s (/ 1 base)]  ;; A multiplicand to shift to the right of the decimal.
     ;; We essentially want to reverse the digits of n and put them after the
     ;; decimal point. So, we repeatedly pull off the lowest digit of n, scale
     ;; it to the right of the decimal point, and accumulate that.
     (loop [sum 0
            n n
            scale s]
       (if (zero? n)
         sum  ;; Base case: no digits left, so we're done.
         (recur (+ sum (* (rem n base) scale))  ;; Accumulate the least digit
                (quot n base)                   ;; Drop a digit of n
                (* scale s)))))))               ;; Move farther past the decimal

(clojure.pprint/print-table
  (cons :base (range 10))  ;; column headings
  (for [base (range 2 6)]  ;; rows
    (into {:base base}
          (for [n (range 10)]  ;; table entries
            [n (van-der-corput n base)]))))