Problem Statement

While similar to both Bulls and cows and Mastermind, Wordle is a notable variation, having experienced a viral surge in popularity, and reverse engineering the game or creating variants has become a popular programming exercise. However, a sampling of the "code a Wordle clone" videos on YouTube shows that seven of the eight reviewed had a serious flaw in the way that they assigned colours to the letters of a guessed word. This aspect of the game is described here: en.wikipedia.org/wiki/Wordle#Gameplay Create a function or procedure that takes two strings; the answer string, and the guess string, and returns a string, list, dynamic array or other ordered sequence indicating how each letter should be marked as per the description above. (e.g. "green", "yellow", or "grey", or, equivalently, the integers 2, 1, or 0 or suchlike.) You can assume that both the answer string and the guess string are the same length, and contain only printable characters/code points in the ASCII/UniCode Range ! to ~ (hex 20 to 7F) and that case is significant. (The original game only uses strings of 5 characters, all alphabetic letters, all in the same case, but this allows for most existing variants of the game.) Provide test data and show the output here. The test data should include the answer string ALLOW and the guess string LOLLY, and the result should be (yellow, yellow, green, grey, grey) or equivalent.

Let's start with the solution:

import std/[strformat, strutils]

type Color {.pure.} = enum Grey = "grey", Yellow = "yellow", Green = "green"

proc wordle(answer, guess: string): seq[Color] =
  let n = guess.len
  if answer.len != n:
    quit "The words must be of the same length.", QuitFailure
  var answer = answer
  result.setLen(n)
  for i in 0..<n:
    if guess[i] == answer[i]:
      answer[i] = '\0'
      result[i] = Green
  for i in 0..<n:
    let ix = answer.find(guess[i])
    if ix >= 0:
      answer[ix] = '\0'
      result[i] = Yellow

const Pairs = [["ALLOW", "LOLLY"],
               ["BULLY", "LOLLY"],
               ["ROBIN", "ALERT"],
               ["ROBIN", "SONIC"],
               ["ROBIN", "ROBIN"]]

for pair in Pairs:
  let res  = wordle(pair[0], pair[1])
  echo &"""{pair[0]} v {pair[1]} → ({res.join(", ")})"""