Problem Statement

While similar to both Bulls and cows and Mastermind, Wordle is a notable variation, having experienced a viral surge in popularity, and reverse engineering the game or creating variants has become a popular programming exercise. However, a sampling of the "code a Wordle clone" videos on YouTube shows that seven of the eight reviewed had a serious flaw in the way that they assigned colours to the letters of a guessed word. This aspect of the game is described here: en.wikipedia.org/wiki/Wordle#Gameplay Create a function or procedure that takes two strings; the answer string, and the guess string, and returns a string, list, dynamic array or other ordered sequence indicating how each letter should be marked as per the description above. (e.g. "green", "yellow", or "grey", or, equivalently, the integers 2, 1, or 0 or suchlike.) You can assume that both the answer string and the guess string are the same length, and contain only printable characters/code points in the ASCII/UniCode Range ! to ~ (hex 20 to 7F) and that case is significant. (The original game only uses strings of 5 characters, all alphabetic letters, all in the same case, but this allows for most existing variants of the game.) Provide test data and show the output here. The test data should include the answer string ALLOW and the guess string LOLLY, and the result should be (yellow, yellow, green, grey, grey) or equivalent.

Let's start with the solution:

var colors = ["grey", "yellow", "green"]

var wordle = Fn.new { |answer, guess|
    var n = guess.count
    if (answer.count != n) Fiber.abort("The words must be of the same length.")
    answer = answer.toList
    var result = List.filled(n, 0)
    for (i in 0...n) {
        if (guess[i] == answer[i]) {
            answer[i] = "\0"
            result[i] = 2
        }
    }
    for (i in 0...n) {
        var ix = answer.indexOf(guess[i])
        if (ix >= 0) {
            answer[ix] = "\0"
            result[i] = 1
        }
    }
    return result
}

var pairs = [
    ["ALLOW", "LOLLY"],
    ["BULLY", "LOLLY"],
    ["ROBIN", "ALERT"],
    ["ROBIN", "SONIC"],
    ["ROBIN", "ROBIN"]
]
for (pair in pairs) {
    var res  = wordle.call(pair[0], pair[1])
    var res2 = res.map { |i| colors[i] }.toList
    System.print("%(pair[0]) v %(pair[1]) => %(res) => %(res2)")
}