Problem Statement

In strict functional programming and the lambda calculus, functions (lambda expressions) don't have state and are only allowed to refer to arguments of enclosing functions. This rules out the usual definition of a recursive function wherein a function is associated with the state of a variable and this variable's state is used in the body of the function. The   Y combinator   is itself a stateless function that, when applied to another stateless function, returns a recursive version of the function. The Y combinator is the simplest of the class of such functions, called fixed-point combinators.

Define the stateless   Y combinator   and use it to compute factorials and Fibonacci numbers from other stateless functions or lambda expressions.

Let's start with the solution:

var y = Fn.new { |f|
    var g = Fn.new { |r| f.call { |x| r.call(r).call(x) } }
    return g.call(g)
}

var almostFac = Fn.new { |f| Fn.new { |x| x <= 1 ? 1 : x * f.call(x-1) } }

var almostFib = Fn.new { |f| Fn.new { |x| x <= 2 ? 1 : f.call(x-1) + f.call(x-2) } }

var fac = y.call(almostFac)
var fib = y.call(almostFib)

System.print("fac(10) = %(fac.call(10))")
System.print("fib(10) = %(fib.call(10))")