Problem Statement

Just as numbers can be represented in a positional notation as sums of multiples of the powers of ten (decimal) or two (binary); all the positive integers can be represented as the sum of one or zero times the distinct members of the Fibonacci series. Recall that the first six distinct Fibonacci numbers are: 1, 2, 3, 5, 8, 13. The decimal number eleven can be written as 013 + 18 + 05 + 13 + 02 + 01 or 010100 in positional notation where the columns represent multiplication by a particular member of the sequence. Leading zeroes are dropped so that 11 decimal becomes 10100. 10100 is not the only way to make 11 from the Fibonacci numbers however; 013 + 18 + 05 + 03 + 12 + 11 or 010011 would also represent decimal 11. For a true Zeckendorf number there is the added restriction that no two consecutive Fibonacci numbers can be used which leads to the former unique solution.

Generate and show here a table of the Zeckendorf number representations of the decimal numbers zero to twenty, in order.
The intention in this task to find the Zeckendorf form of an arbitrary integer. The Zeckendorf form can be iterated by some bit twiddling rather than calculating each value separately but leave that to another separate task.

Let's start with the solution:

  [ 2 base put
    echo
    base release ]        is binecho ( n -->   )

  [ 0 swap ' [ 2 1 ]
    [ 2dup 0 peek < iff
        [ behead drop ]
        done
      dup 0 peek
      over 1 peek
      + swap join again ]
    witheach
      [ rot 1 << unrot
        2dup < iff drop
        else
          [ -
            dip
              [ 1 | ] ] ]
    drop ]                is n->z    ( n --> z )

  [ 0 temp put
    1 1 rot
    [ dup while
      dup 1 & if
        [ over
          temp tally ]
      1 >>
      dip [ tuck + ]
      again ]
    2drop drop
    temp take ]           is z->n    ( z --> n )

   21 times
     [ i^ dup echo
       say " -> "
       n->z dup binecho
       say " -> "
       z->n echo cr ]