Problem Statement

Langton's ant is a cellular automaton that models an ant sitting on a plane of cells, all of which are white initially, the ant facing in one of four directions. Each cell can either be black or white. The ant moves according to the color of the cell it is currently sitting in, with the following rules: This rather simple ruleset leads to an initially chaotic movement pattern, and after about 10000 steps, a cycle appears where the ant moves steadily away from the starting location in a diagonal corridor about 10 cells wide.
Conceptually the ant can then walk infinitely far away.

Start the ant near the center of a 100x100 field of cells, which is about big enough to contain the initial chaotic part of the movement. Follow the movement rules for the ant, terminate when it moves out of the region, and show the cell colors it leaves behind.

The problem has received some analysis; for more details, please take a look at the Wikipedia article   (a link is below)..

Let's start with the solution:

package require Tk

proc step {workarea} {
    global x y dir
    if {[lindex [$workarea get $x $y] 0]} {
	$workarea put black -to $x $y
	if {[incr dir] > 3} {set dir 0}
    } else {
	$workarea put white -to $x $y
	if {[incr dir -1] < 0} {set dir 3}
    }
    switch $dir {
	0 {incr x}
	1 {incr y}
	2 {incr x -1}
	3 {incr y -1}
    }
    expr {$x < 0 || $x >= [image width $workarea] || $y < 0 || $y >= [image height $workarea]}
}

image create photo antgrid -width 100 -height 100
pack [label .l -image antgrid]
antgrid put white -to 0 0 99 99
set x [set y 50]
set dir 0

while 1 {
    update
    if {[step antgrid]} break
}

# Produce output in file
antgrid write ant.gif -format gif